陈德馨

Ghost安装Win7/XP后自动恢复IP的批处理

737人参与 |分类: 工具库|时间:2012年10月30日 14:24

对于我这种经常帮人家安装系统的IT民工来说,最烦恼的就是需要在重装系统之前手动记录下人家原来的IP设置,家庭还好,电脑不多,要是公司的话,这项工作就必须做了,要不然动不动就是IP冲突之类的。所以,我经过摸索之后写了一个脚本,大概功能就是在Ghost安装系统之前先导出原来系统的IP信息,在Ghost完成之后,自动读取这个IP信息用于恢复IP设置。

1、导出WinXP系统IP信息:

@echo off&setlocal enabledelayedexpansion
title WindowsXP IP信息导出工具(配合IP恢复脚本使用所用)
echo IP信息正在导出...
for /f "tokens=1,2 delims=:" %%i in ('ipconfig') do (
echo %%i | find /i "IP Address">nul && echo IP:%%j>D:\ip.txt
echo %%i | find /i "Subnet Mask">nul && echo MK:%%j>>D:\ip.txt
if "!GW!" equ "1" call :end
echo %%i | find /i "Default Gateway">nul && echo GW:%%j>>D:\ip.txt && set GW=1
)
:end
echo=
echo 导出IP信息完毕,请按任意键检查...
pause>nul
start "" d:\ip.txt
exit

2、导出Win7系统IP信息:

@echo off&setlocal enabledelayedexpansion
title Windows 7 IP信息导出工具(配合IP恢复脚本使用)
echo IP信息正在导出...
for /f "tokens=1,2 delims=:" %%i in ('ipconfig') do (
echo %%i | find /i "IPv4 位址">nul && echo IP:%%j>D:\ip.txt
echo %%i | find /i "子网掩码">nul && echo MK:%%j>>D:\ip.txt
if "!GW!" equ "1" call :end
echo %%i | find /i "预设网关">nul && echo GW:%%j>>D:\ip.txt && set GW=1
)
:end
echo=
echo 导出IP信息完毕.请按任意键检查...
pause>nul
start "" d:\ip.txt
exit

Ps:测试过程中,发现win7 使用ipconfig命令,会有个IPv6的网关,导致出错,只好用了一个 if 跳出循环。

3、最后输出到D:\ip.txt的格式如下:

IP: 10.197.198.180

MK: 255.255.255.254

GW: 10.197.198.1

最后,通过下面这个脚本读取d:\IP.txt内容并恢复IP:

@echo off&setlocal enabledelayedexpansion
title Ghost系統后的IP恢复工具
rem 判断文件是否存在
if not exist d:\ip.txt goto error
rem 从IP.txt读取信息,并設置变量
for /f "tokens=1,2 delims=: " %%a in (d:\ip.txt) do (
if /i "%%a"=="IP" set addr=%%b
if /i "%%a"=="MK" set mask=%%b
if /i "%%a"=="GW" set gateway=%%b
)
rem 获取第一块网卡的名称,并设置IP,多块网卡将设置第一块
for /f tokens^=1^,2^ delims^=^" %%j in ('netsh interface ip show config') do (
if "%%j"=="介面 " (
netsh interface ip set address name="%%k" source=static addr=!addr! mask=!mask! gateway=!gateway!
call :end
)
if "%%j"=="接口 " (
netsh interface ip set address name="%%k" source=static addr=!addr! mask=!mask! gateway=!gateway!
call :end
)
)
:end
echo 设置完毕,3S后自动退出!
ping -n 3 127.1 >nul
exit
:error
cls
echo 错误:D盘根目录未发现IP.TXT文件!请您手动设置IP,请按任意键推出...
pause>nul
exit

这个脚本简、繁WinXP/7等系统都可以兼容设定IP。还是非常方便的。

4、脚本用法:

1、封装Ghost系统镜像时,将设置IP的脚本加入启动项

2、Ghost安装系统之前先通过【导出脚本】或【手动的方法】在d盘建立ip.txt,写入如上三条信息

3、通过oneKey远程恢复Ghost系统镜像,等恢复完成之后,IP脚本自动恢复D盘设定好的IP,这时就可以远程连接电脑进行维护了,整个过程均不需要现场操作。

来源:陈德馨博客(微信/QQ号:35435164),转载请保留出处和链接!

地址:

必填

选填

选填

◎已有 0 人评论,请发表您的观点。